Syntax

MIN(some-list)

Arguments

  • some-list (list of any numeric type)

AppSheet must be given enough context to determine what type of values some-list contains, that its contents are or will be numeric. To that end, some-list must be one of the following: a column value of type List that contains numeric values; a column list (e.g., Products[Price]) for a column of a numeric type; or a constructed list (e.g., with LIST()) of a numeric type.

Return Value

The lowest value in some-list.

Examples

MIN(Products[Price]) : The lowest of all values in the Price column of the Products table. Equivalent to MIN(SELECT(Products[Price], TRUE)). See also SELECT().

MIN([Discounts]) : The lowest of the items in the Discounts column value, where Discounts is of type List.

MIN(LIST(1, 2, 3)) returns Number: 1

Lowest from Select Values

Lowest sale price to non-employees within the past six months:

MIN(
  SELECT(
    Sales[Sale Price],
    AND(
      ISNOTBLANK([Sale Price]),
      NOT([Customer].[Is Employee?]),
      ([Sale Date] > (
        EOMONTH(TODAY(), -7) + DAY(TODAY())
      ))
    )
  )
)
  1. SELECT(Sales[Sale Price], ...) returns a list of values from the Sale Price column from rows of the Sales table.
  2. AND(..., ..., ...) limits the values returned to only those from rows that match all of the given conditions.
  3. ISNOTBLANK([Sale Price]) includes only rows with a non-blank Sale Price column value.
  4. NOT([Customer].[Is Employee?]) excludes rows with a Customer column value that refers to a customer record that indicates the customer is also an employee.
  5. [Sale Date] > ... includes only rows with a Sale Date column value later than the computed date.
  6. EOMONTH(TODAY(), -7) + DAY(TODAY() computes the date for six month ago today.
  7. MIN(...) returns the lowest value in the select list of Sale Price values.

See also: AND(), DAY(), EOMONTH(), ISNOTBLANK(), NOT(), SELECT(), TODAY()

Common Problems

MIN(1, 2, 3) : the arguments are not in list form. To fix, wrap them in LIST() to construct a list: MIN(LIST(1, 2, 3)).

See Also

AVERAGE(), COUNT(), MAX(), STDEVP(), SUM()

Did this answer your question?