Syntax

LEFT(some-text, how-many)

Arguments

  • some-text (any textual)
  • how-many (Number) : The number of characters from some-text to return. Non-Number values may be accepted but may produce unexpected results.

Return Value

Text: The first how-many characters from some-text. If how-many is greater than the length of some-text or less than 0, some-text is returned in its entirety.

Examples

LEFT("123 Maple Dr", 5) : 123 M

LEFT("123 Maple Dr", 0) returns blank.

First & Last Initials

Initials from a first and last name:

LEFT([First Name], 1) & LEFT([Last Name], 1)
  • LEFT(..., 1) gets the first character of the specified column value.
  • LEFT(...) & LEFT(...) concatenates the two initials into a single text value.

Equivalent to INITIALS(CONCATENATE([First Name], " ", [Last Name])).

See also: CONCATENATE(), INITIALS()

Integer Component of Decimal Value

The integer component of a Decimal value in the Result column:

NUMBER(
  LEFT(
    TEXT([Result]),
    (FIND(".", TEXT([Result])) - 1)
  )
)
  • TEXT([Result]) converts the Decimal value to a Text value. The textual functions used in this example interpret non-textual values differently. Using TEXT() ensures the Result column value is interpreted the same by each function.
  • (FIND(".", ...) - 1) locates the character immediately preceding the decimal point.
  • LEFT(..., ...) extracts the integer part.
  • NUMBER(...) converts the extracted text to a Number.

Equivalent to FLOOR([Result]).

See also: FIND(), FLOOR(), NUMBER(), TEXT()

Street Number from Street Address

The first word of an address, which is typically the street number:

LEFT([Address], (FIND(" ", [Address]) - 1))
  • FIND(" ", [Address]) locates the first/leftmost space in the Address column value.
  • FIND(...) - 1 locates the character immediately preceding the first space.
  • LEFT([Address], ...) returns the leftmost text preceding the first space.

Equivalent to INDEX(SPLIT([Address], " "), 1).

See also: FIND(), INDEX(), SPLIT()

See Also

INITIALS(), MID(), RIGHT()

Did this answer your question?