RIGHT()

Examples

RIGHT("123 Maple Dr", 5) : le Dr

RIGHT("123 Maple Dr", 0) returns blank.

Fractional Component of Decimal Value

The fractional component of a Decimal value in the Result column:

NUMBER(
  RIGHT(
    TEXT([Result]),
    (LEN(TEXT([Result]))
      - FIND(".", TEXT([Result])))
  )
)

TEXT([Result]) converts the Decimal value to a Text value. The textual functions used in this example interpret non-textual values differently. Using TEXT() ensures the Result column value is interpreted the same by each function.
FIND(".", ...) locates the decimal point in the value.
(LEN(...) - FIND(...)) calculates the length of the fractional component by subtracting the length of the non-fraction part from the entire length.
RIGHT(..., ...) extracts the fractional part.
NUMBER(...) converts the extracted text to a Number.

See also: FIND(), LEN(), NUMBER(), TEXT()

Street Name from Street Address

Everything after the first word of a street address, which is typically the street name:

RIGHT([Address], (LEN([Address]) - FIND(" ", [Address])))

FIND(" ", [Address]) locates the first/leftmost space in the Address column value.
LEN([Address]) - FIND(...) calculates the length of the Address column value beyond the first space by subtracting the length of the text preceding the first space from the total length.
RIGHT([Address], ...) returns the rightmost text following the first space.

Syntax

RIGHT( some-text , how-many )

Arguments

some-text (any textual type)
how-many (Number) : The number of characters from some-text to return. Non-Number values may be accepted but may produce unexpected results.

Return Value

Text: The last how-many characters from some-text. If how-many is greater than the length of some-text or less than 0, some-text is returned in its entirety.